;;Page Break Attribute

/*

Objective :

	In this example, Page Break: TSPL ClosingPageLine, TSPL OpeningPageLine 
	ensures that the specified closing and opening lines are displayed whenever 
	the content continues onto a new page.

;;Syntax

[Part : <Part Name>]
 Page Break : <Closing Page Line>, <Opening Page Line>

*/

[#Menu: Gateway of Tally]
	Add: Item: "Page Break attribute" : Display : TSPL PageBreakAttribute
	
[Report: TSPL PageBreakAttribute]
	Form: TSPL PageBreakAttribute
	
[Form: TSPL PageBreakAttribute]
	Part: TSPL PageBreakAttribute
	
	[Part: TSPL PageBreakAttribute]
		Line	: TSPL LedgerTitles,TSPL LedgerDetails
		Repeat	: TSPL LedgerDetails	: List of Ledgers 	;;The line "TSPL LedgerDetails" is repeated over the "List of Ledgers" collection using this repeat attribute.
		Scroll	: Vertical									;;This attribute allows repeated lines in the Part to be scrolled.
		Common Border: Yes									;;This attribute allows borders from one line to extend across other lines within the Part.
		Float	: No										;;This attribute when set to 'No' it keeps the Bottom line at the end of the part.
		Border	: Thin Box
		Page Break: TSPL ClosingPageLine, TSPL OpeningPageLine
		
		[Line: TSPL ClosingPageLine]
			Field	: TSPL ClosingPageLine
			
			[Field: TSPL ClosingPageLine]
				Use		: Name Field
				Set as	: "To be continued...."
				Full Width: Yes
				Align	: Right
				Style	: Small Bold
			
		[Line: TSPL OpeningPageLine]
			Use	: TSPL LedgerTitles
		
		[Line: TSPL LedgerTitles]
			Field: TSPL LedgerName,TSPL LedgerParent,TSPL LedgerOp,TSPL LedgerCl
			Local: Field: Default			: Type	: String
			Local: Field: Default			: Align : Center
			Local: Field: Default			: Style	: Normal Bold
			
			Local: Field: TSPL LedgerName  	: Set as: "Ledger Name"
			Local: Field: TSPL LedgerParent	: Set as: "Parent"
			Local: Field: TSPL LedgerOp		: Set as: "Opening Bal"
			Local: Field: TSPL LedgerCl		: Set as: "Closing Bal"
			Border: Thin Bottom

		[Line: TSPL LedgerDetails]
			Field: TSPL LedgerName,TSPL LedgerParent,TSPL LedgerOp,TSPL LedgerCl
			
			[Field: TSPL LedgerName]
				Use		: Name Field
				Set as	: $Name				;;Methods are extracted and displayed based on the objects in the collection.
				Width	: 5 Cms
				Border	: Thin Right

			[Field: TSPL LedgerParent]
				Use		: Name Field
				Set as	: $Parent
				Width	: 4 Cms
				Border	: Thin Right
				
			[Field: TSPL LedgerOp]
				Use		: Amount Field
				Set as	: $OpeningBalance
				Width	: 3 Cms
				Border	: Thin Right
				
			[Field: TSPL LedgerCl]
				Use		: Amount Field
				Set as	: $ClosingBalance
				Width	: 3 Cms
				
;;End of File