[#Form	: Sales Color]
	
	Delete	: Print
	Add		: Print	: TSPL Print Vch Details
	
[Report	: TSPL Print Vch Details]
	
	Form	: TSPL Print Vch Details
	Object	: Voucher
	
[Form: TSPL Print Vch Details]
	
	Part	: TSPL Print Cmp Details, TSPL Print Vch LedDtls, TSPL Print Vch
	
	[Part	: TSPL Print Cmp Details]
		
		ObjectEx	: (Company,##SVCurrentCompany).
		Line		: TSPLCmpName, TSPLCmpAdd
		Repeat		: TSPLCmpAdd	: Address
		Scroll 		: Flow
		Local		: Field		: Default : Full Width	: Yes
		Local		: Field		: Default : Align		: Center
		Border		: Thick Top Bottom
		
		[Line	: TSPLCmpName]
			
			Field	: Name Field
			Local	: Field		: Name Field	: Info	: $Name
			Local	: Field		: Name Field	: Style	: Extra Large Bold
			
		[Line	: TSPLCmpAdd]
			
			Field	: Name Field
			Local	: Field		: Name Field	: Info	: $Address
			Local	: Field		: Name Field	: Style	: Normal
			

	[Part	: TSPL Print Vch LedDtls]
		
		Object	: LedgerEntries	: First
		
		Line	: TSPL PName, TSPLPClBal, TSPLPBillAllocT, TSPLPBillAllocBT, TSPLPBillAlloc
		Repeat	: TSPLPBillAlloc	: BillAllocations
		Scroll	: Flow
		
		[Line	: TSPL PName]
			
			Field	: Long Prompt, Name Field
			Local	: Field		: Long Prompt	: Info		: "Party Ledger Name"
			Local	: Field		: Name Field	: Set as	: $LedgerName
			
		[Line	: TSPLPClBal]
			
			Field	: Long Prompt, Amount Field
			Local	: Field		: Long Prompt	: Info		: "Closing Balance"
			Local	: Field		: Amount Field	: Set as	: $ClosingBalance:Ledger:$LedgerName
			Local	: Field		: Amount Field	: Format	: "DrCr"

		[Line	: TSPLPBillAllocT]
			
			Field	: TSPLPBillAllocT
			Border	: Thick Box
			
			[Field	: TSPLPBillAllocT]
				
				Full Width	: Yes
				Info		: "Party Ledger Bills"
				Align		: Center
				Style		: Large Bold
				
		[Line	: TSPLPBillAllocBT]
			
			Use		: TSPLPBillAlloc
			Local	: Field	: Default			: Style	: Normal Bold
			Local	: Field	: Default			: Type	: String
			Local	: Field	: Default			: Line	: 0

			Local	: Field	: TSPLBillName		: Info : "Bill Name"
			Local	: Field	: TSPLBillAMount	: Info : "Bill Amount"
			Border	: Thin Bottom
			
		[Line	: TSPLPBillAlloc]
			
				Field	: TSPLBillName, TSPLBillAMount
				
				[Field	: TSPLBillName]
					
					Use		: Name Field
					Set as	: $Name
					
				[Field	: TSPLBillAMount]
					Use		: Amount Field
					Set as	: $Amount
					Format	: "DrCr"

	[Part	: TSPL Print Vch]
		
		Part	: TSPL Print Vch Details, TSPL Print Vch DetailsDtl
		Vertical: Yes
		
		[Part	: TSPL Print Vch Details]
			
			Line	: TSPL Print Vch Dt, TSPL Print Vch Num
			Border	: Thin Top
			
			[Line	: TSPL Print Vch Dt]
				
				Field	: Long prompt, Uni Date Field
				Local	: Field		: Long prompt	: Info	: "Voucher Date"
				Local	: Field		: Uni Date Field: Set as: $Date
			
			[Line	: TSPL Print Vch Num]
				
				Field	: Long prompt, Short Name Field
				Local	: Field		: Long prompt		: Info	: "Invoice Number"
				Local	: Field		: Short Name Field	: Set as: $VoucherNumber

		[Part	: TSPL Print Vch DetailsDtl]
			
			Line	: TSPL Print Vch DetailsDtlT, TSPL Print Vch DetailsDtlB
			Repeat	: TSPL Print Vch DetailsDtlB	: InventoryEntries
			Scroll	: Flow
			
			[Line	: TSPL Print Vch DetailsDtlT]
				
				Use	: TSPL Print Vch DetailsDtlB
				
				Local	: Field	: TSPL StkName		: Info : "Particulars"
				Local	: Field	: TSPLStkAQty       : Info : "Actual Qty"
				Local	: Field	: TSPLStkBQty       : Info : "Billed Qty"
				Local	: Field	: TSPLStkRate       : Info : "Rate"
				Local	: Field	: TSPLStkAmount     : Info : "Amount"
				
				Local	: Field	: Default			: Style	: Normal Bold
				Local	: Field	: Default			: Type	: String
				Local	: Field	: Default			: Line	: 0
				Border	: Thin Top Bottom

			[Line	: TSPL Print Vch DetailsDtlB]
				
				Field		: TSPL StkName
				Right Field	: TSPLStkAQty,TSPLStkBQty, TSPLStkRate, TSPLStkAmount

				[Field	: TSPLStkName]

					Use			: Name Field
					Set as		: $StockItemName
					Full Width	: Yes
					
				[Field	: TSPLStkAQty]
					
					Use			: Qty Field
					Set as		: $ActualQty
					
				[Field	: TSPLStkBQty]
					
					Use		: QtyField
					Set as	: $BilledQty
					
				[Field	: TSPLStkRate]
					
					Use		: Rate Field
					Set as	: $Rate

				[Field	: TSPLStkAmount]
					
					Use		: Amount Field
					Set as	: $Amount