;;Graph Type Attribute

/*

This example demonstrates how the Graph Type attribute is used to display a bar graph within a part. 
When Graph Type: Yes is applied, the system renders the data in a graphical bar format. 
To show the X and Y axes, the part must include two fields with Graph Label: Yes, 
which define the labels for each axis. 

;;Syntax

[Part : <Part Name>]
  GraphType : <Logical expression>

*/

[#Menu: Gateway of Tally]
	Add: Item: "Graph Type attribute" : Display : TSPL GraphTypeAttribute
	
[Report: TSPL GraphTypeAttribute]
	Title : "Graph Type Attribute in Part definition"
	Form  : TSPL GraphTypeAttribute
	
[Form: TSPL GraphTypeAttribute]
	Part  : TSPL GraphTypeAttribute
	Width : 50% Page

	[Part: TSPL GraphTypeAttribute]
		Line  : TSPL GraphTypeAttribute 
		Repeat: TSPL GraphTypeAttribute : TSPL Indirect Expenses collection
		Border: Thin Box	
		Graph Type	: Yes	
		
	[Line: TSPL GraphTypeAttribute]
		Field       : TSPL Indirect Expenses Graph Particulars, TSPL Indirect Expenses Graph value

		Local: Field: TSPL Indirect Expenses Graph Particulars	: Graph Label	: Yes
		
		[Field: TSPL Indirect Expenses Graph Particulars]
			
			Use			: Name Field
			Set as		: $Name
			Graph Label : Yes
			Alter		: Ledger
				
		[Field: TSPL Indirect Expenses Graph value]
			
			Use         : Amount Field
			Style		: Large Bold
			Set as		: $Closingbalance
			Graph Value : Yes	
			Background	: First BarGraph Color

;; Ledger collection to get ledger name and closing balance in report.

[Collection: TSPL Indirect Expenses collection]
	
		Type: Ledger
		Child Of: $$GroupIndirectExpenses
		
		Fetch: Name, Closingbalance
		Sort : @@Default : $Closingbalance  
		Max  : 10
		
		
;;End of File