;;Excel Autofit Attribute

/*

-	In this example, "Excel AutoFit : Yes" enables the auto-fit feature for the exported 
	Excel sheet, ensuring that cell widths are adjusted according to the field values.
-	This attribute improves the readability of the exported Excel file by preventing 
	content from being truncated or unnecessarily compressed.

;;Syntax

[Part : <Part Name>]
 Excel AutoFit : <Logical Value>

*/

[#Menu: Gateway of Tally]
	
	Add: Item: "Excel Autofit attribute" : Display : TSPL ExcelAutofitAttribute
	
[Report: TSPL ExcelAutofitAttribute]
	
	Form: TSPL ExcelAutofitAttribute
	
[Form: TSPL ExcelAutofitAttribute]
	
	Part: TSPL ExcelAutofitAttribute
	Height: 100% Screen
	
	[Part: TSPL ExcelAutofitAttribute]
		
		Line	: TSPL ExcelAutofitTitle,TSPL ExcelAutofitDetails
		Repeat	: TSPL ExcelAutofitDetails : TSPL LedgerCollection
		Scroll	: Both
		Float	: No
		Excel AutoFit: Yes		;;This attribute will automatically fit the field values in the cell during Excel Export. 

		[Line: TSPL ExcelAutofitTitle]
			
			Field: TSPL LedgerName,TSPL Parent,TSPL Address,TSPL PhoneNo,TSPL Email,TSPL Opening,TSPL Closing
			Local: Field : Default	: Type	: String
			Local: Field : Default	: Style	: Normal Bold
			
			Local: Field : TSPL LedgerName 	: Set as: "Name"
			Local: Field : TSPL Parent		: Set as: "Parent"
			Local: Field : TSPL Address		: Set as: "Address"
			Local: Field : TSPL PhoneNo		: Set as: "Phone No"
			Local: Field : TSPL Email		: Set as: "Email"
			Local: Field : TSPL Opening		: Set as: "Opening Balance"
			Local: Field : TSPL Closing		: Set as: "Closing Balance"
			Height: 5.5 mms
			Border: Totals
			
		[Line: TSPL ExcelAutofitDetails]
			
			Field: TSPL LedgerName,TSPL Parent,TSPL Address,TSPL PhoneNo,TSPL Email,TSPL Opening,TSPL Closing
			Local: Field : Default 			: Style	: Normal
			
			[Field: TSPL LedgerName]
				
				Use		: Name Field
				Set as	: $Name
				Style	: Normal Bold
				Width	: 30% Screen
				
			[Field: TSPL Parent]
				
				Use		: Name Field
				Set as	: $Parent
				Style	: Normal Bold
				Width	: 20% Screen
				
			[Field: TSPL Address]
				
				Use		: Name Field
				Set as	: $$FullList:Address:$Address
				Style	: Normal Bold
				Width	: 30% Screen
				
			[Field: TSPL PhoneNo]
				
				Use		: Name Field
				Set as	: $MobileNo
				Style	: Normal Bold
				Width	: 10% Screen
				
			[Field: TSPL Email]
				
				Use		: Name Field
				Set as	: $Email
				Style	: Normal Bold
				Width	: 20% Screen
				
			[Field: TSPL Opening]
				
				Use		: Amount Field
				Set as	: $OpeningBalance
				Style	: Normal Bold
				Width	: 10% Screen
				
			[Field: TSPL Closing]
				
				Use		: Amount Field
				Set as	: $ClosingBalance
				Style	: Normal Bold
				Width	: 10% Screen
				
[Collection: TSPL LedgerCollection]
	
	Type	: Ledger
	
	Fetch	: Name, Parent, Address, MobileNo, Email, OpeningBalance, ClosingBalance
	

;;End of File