;;Enable Graph Cursor Attribute

/*

The Enable Graph Cursor attribute is used to allow cursor movement on a graph.
When this attribute is set to Yes, the user can move the cursor over different data points on the graph to 
view more details.
This example demonstrates how the Enable Graph Cursor attribute makes the graph interactive.
The Part repeats for each item in the TSPL Indirect Expenses collection.
Since Enable Graph Cursor: Yes is used, the cursor can move across the graph.
When combined with Graph Display Cursor Label: Yes, the user can also see the exact value of each data point 
when the cursor stops on it.

;;Syntax

[Part : <Part Name>]
  Enable Graph Cursor : <Logical expression>

*/

[#Menu: Gateway of Tally]
	Add: Item: "Enable Graph Cursor attribute" : Display : TSPL EnableGraphCursorAttribute
	
[Report: TSPL EnableGraphCursorAttribute]
	Title : "Enable Graph Cursor Attribute in Part definition"
	Form  : TSPL EnableGraphCursorAttribute
	
[Form: TSPL EnableGraphCursorAttribute]
	Part  : TSPL EnableGraphCursorAttribute
	Width : 50% Page

	[Part: TSPL EnableGraphCursorAttribute]
		Line  : TSPL EnableGraphCursorAttribute 
		Repeat: TSPL EnableGraphCursorAttribute : TSPL Indirect Expenses collection
		Border: Thin Box
		Graph Type	: Yes
		Enable Graph Cursor: Yes
		Graph Display Cursor Label: Yes
		
	[Line: TSPL EnableGraphCursorAttribute]
		Field       :  TSPL Indirect Expenses Graph Particulars, TSPL Indirect Expenses Graph value

		Local: Field: TSPL Indirect Expenses Graph Particulars	: Graph Label	: Yes
		
		[Field: TSPL Indirect Expenses Graph Particulars]
			
			Use			: Name Field
			Set as		: $Name
			Graph Label : Yes
			Alter		: Ledger
				
		[Field: TSPL Indirect Expenses Graph value]
			
			Use         : Amount Field
			Style		: Large Bold
			Set as		: $Closingbalance
			Graph Value : Yes	
			Background	: First BarGraph Color

;; Ledger collection to get ledger name and closing balance in report.

[Collection: TSPL Indirect Expenses collection]
	
		Type: Ledger
		Child Of: $$GroupIndirectExpenses
		
		Fetch: Name, Closingbalance
		Sort : @@Default : $Closingbalance  
		Max  : 10
		
		
;;End of File