/*
Objective(s)
- AccessName acts like a label or shortcut name for a Part, making it easy to find and use it wherever required.
- The AccessName attribute assigns a unique name to a Part so it can be easily identified and 
  accessed elsewhere in the code.
- In this example, AccessName : "Cash" uniquely identifies the part TSPL AccessObj1. 
- This allows the system to directly refer to this part and link it to the Cash Ledger during execution, 
  without ambiguity.
	
Syntax : 

[Part : <Part Name>]
	Access Name : <Access Name Formula>

*/

;;Example to demonstrate the usage of 'AccessName' attribute at 'Part' definition.

[#Menu: Gateway of Tally]
	Add: Item: "AccessName Attribute" : Display : TSPL AccessObj

[Report: TSPL AccessObj]

	Form		: TSPL AccessObj
	Full Screen	: No
	Fetch Object: Ledger		: "Cash"			: Name
	Fetch Object: Group			: "Unsecured Loans"	: Name

[Form: TSPL AccessObj]

	Parts		: Form SubTitle, TSPL AccessObj1, TSPL AccessObj2, TSPL AccessObj3
	Local: Field: Form SubTitle	: Info		: "Understanding Function AccessObj"
	Width		: 50% Page

[Part: TSPL AccessObj1]

	Lines		: TSPL AccessObj
	AccessName	: "Cash"				;;AccessName for the Part - TSPL AccessObj1 is set to 'Cash'.
	ObjectEx	: (Ledger, "Cash").
	Border		: Thin Box

	[Line: TSPL AccessObj]

		Fields		: Medium Prompt, TSPL AccessObj
		Local: Field: Medium Prompt		: Set As	: "Part - AccessObj 1"

		[Field: TSPL AccessObj]

			Use		: Name Field
			Set As	: "AO1 - " + $Name

[Part: TSPL AccessObj2]

	Lines		: TSPL AccessObj
	AccessName	: "Unsecured Loans"		;;AccessName for the Part - TSPL AccessObj2 is set to 'Unsecured Loans'.
	ObjectEx	: (Group, "Unsecured Loans").
	Local: Line	: TSPL AccessObj	: Local	: Field: Medium Prompt	: Set As	: "Part - AccessObj 2"
	Local: Line	: TSPL AccessObj	: Local	: Field: TSPL AccessObj		: Set As	: "AO2 - " + $Name
	Border		: Thin Box
	
[Part: TSPL AccessObj3]

	Lines		: TSPL AccessObj3
	Space Top	: 1
	Border		: Thin Box

	[Line: TSPL AccessObj3]

		Fields		: Medium Prompt, AO Part TSPL AccessObj1, AO Part TSPL AccessObj2
		Local: Field: Medium Prompt		: Set As	: "Part AccessObj 1 & 2 :"

		[Field: AO Part TSPL AccessObj1]

			Use		: Name Field
			Set As	: $$AccessObj:Part:"Cash":#TSPLAccessObj	;;Part having the AccessName = Cash is accessed through the AccessObj function, and its field (TSPLAccessObj) value is shown.

		[Field: AO Part TSPL AccessObj2]

			Use		: Name Field
			Set As	: $$AccessObj:Part:"Unsecured Loans":#TSPLAccessObj ;;Part having the AccessName = Unsecured Loans is accessed through the AccessObj function, and its field (TSPLAccessObj) value is shown.

;; End-of-File