;; Sri Ganeshji : Sri Balaji : Sri Pitreshwarji : Sri Durgaji : Sri Venkateshwara

/*
Objective(s) 
- 	This program illustrates the use of following formatting related attributes of Field 

Align 

Border
Border 3D

Background 
Print BG

Color
Print FG
FG Highlight

Type
Format

Full Width
Width
Indent
Space Left
Space Right

Line

Style
Print Style

*/


[#Menu: Gateway of Tally]
	
	Add: Item: ($$LocaleString:"Field Formatting") : Display: TSPL Field Formatting


[Report: TSPL Field Formatting]

	Form 		: TSPL Field Formatting

[Form: TSPL Field Formatting]

	Parts		: TSPL Field Formatting
	Width		: 60% Screen

[Part: TSPL Field Formatting]

	Lines		: TSPL Memo Date, TSPL Memo Title, TSPL Memo Details, TSPL Memo Signed By, TSPL Memo Manager


	[Line: TSPL Memo Date]
		
		Field	: TSPL Memo Date
		
		[Field: TSPL Memo Date]
			
			Type        : Date                   ;; Field holds data type Date
			Width       : @@ShortDateWidth       ;; provides the width of the field
			Style       : Normal Bold            ;; The appearance of the field value will be taken from the style definition Normal Bold
			Format      : Universal Date         ;; The date value will be displayed in universal date format
			Align       : Right                  ;; The date will be right aligned
			Set as		: "11-12-2025"           ;; The value set in the field
			Background	: Crystal Blue           ;; The field will have background color taken from color definition Crystal Blue
			
	[Line: TSPL Memo Title]

		Fields	: TSPL Memo Title
	
		[Field: TSPL Memo Title]

			Set as		: "This is an Important Memo"
			Full Width	: Yes                                     ;; The field takes full width of the form 
			Align		: Center
			Border		: Thin Bottom                             ;; The border drawn for the field is taken from the border definition Thin Bottom
			Border3D	: Yes                                     ;; The border will appear 3D in 3D devices
			Color		: Blue                                    ;; The font color will be taken from the color definition Blue
			Style		: Normal                                   
			FGHighlight	: "Important": Normal Bold 	: Black       ;; The text Important which is a part of the value set in the field is highlighted with style definition NormalBold and Color Black
			
	[Line: TSPL Memo Details]
		
		Field	: TSPL Memo Details
		Space Top: .5
		
		[Field: TSPL Memo Details]
			
			Info		: "Employees are hereby requested to send infromation on total data entered in tally in the form of daily worksheet at the end of the day without fail"
			Style		: Small
			FGHighlight	: "daily worksheet": Small Bold 	: Black
			Indent		: 2                                          ;; The field is indented by 2 characters
			Space Right	: 1.5                                        ;; Space of 2 characters is provided in right of the field
			Full Width	: Yes
			Lines		: 0                                          ;; The field content will be word wrapped
			Print BG	: Yellow                                     ;; background color of the field in print will be taken from color definition yellow
			Print FG	: Red                                        ;; font color of the field in print will be taken from color definition Red
			Print Style	: Large                                      ;; The appearance of the font in print will be taken from the style definition Large
			
	[Line: TSPL Memo Signed By]
		
		Right Field	: TSPL Memo Signed By
		Space Top	: .5
		
		[Field: TSPL Memo Signed By]
			
			Info		: "by,"
			Space Left	: .5                                       ;;0.5 characters of space is left side of the field value
			Space Right	: 7
			
	[Line: TSPL Memo Manager]
		
		Right Field: TSPL Memo Manager
		
		[Field: TSPL Memo Manager]
			
			Info		: "The Manager"
			Space Right	: 2
			
			
			
;;EOF