;; Sri Ganeshji : Sri Balaji : Sri Pitreshwarji : Sri Durgaji : Sri Venkateshwara

/*
Objective(s) 
- 	This program illustrates the use of following attributes of Field 

Add/Replace/Delete

Alter
Display
Variable

DMPMode

Pre Printed
Pre Printed Border

Quick Search

Cell
Skip Cell

JSON Tag/XML Tag
XMLAttr

Fixed
Scroll

*/


[#Menu: Gateway of Tally]
	
	Add: Item: ($$LocaleString:"Tabular Report") : Display: TSPL CustomerDetailsXMLJSON

[Report:  TSPL CustomerDetailsXMLJSON]

	Form        		: TSPL CustomerDetailsXMLJSON
	Title       		: "Company Ledger List"

[Form: TSPL CustomerDetailsXMLJSON]

	Parts       : TSPL CustomerDetailsXMLJSON
	Width		: 100% Screen
	Height		: 100% Screen
	
[Part: TSPL CustomerDetailsXMLJSON]

	Lines       : TSPL CustomerDetailsXMLJSONTitle,TSPL CustomerDetailsXMLJSON
	Repeat      : TSPL CustomerDetailsXMLJSON	: TSPL CustomerDetails
	CommonBorder: Yes
	Scroll      : Vertical
	JSON Tag As Desc Name	: No
	
	[Line: TSPL CustomerDetailsXMLJSONTitle]
		
		Fields      : TSPL Customer Led No, TSPL Customer Led Name, TSPL Customer Led Address, TSPL Customer Led States, TSPL Customer Led Pin, TSPL Customer Led Cont, TSPL Customer Led Tel, TSPL Customer Led FaxNo, TSPL Customer Led EmailAdd, TSPL Customer Led CB
		Repeat		: TSPL Customer Led CB
		Local		: Field: Default: Delete: Type                                             ;; The Type attribute is locally deleted from all fields within this line context
		Local		: Field: Default: Delete: JSONTag
		Local		: Field: Default: Delete: Border
		
		Local		: Field: Default: Add:Pre Printed		: Yes                               ;; When printed on pre printed paper values corresponding to the fields will be ignored
		
		Local		: Field: TSPL Customer Led No		: Add:Info: $$LocaleString:"No."        ;; Info is added to the mentioned fields in the context of this line
		Local		: Field: TSPL Customer Led Name		: Add:Info: $$LocaleString:"Name"
		Local		: Field: TSPL Customer Led Address	: Add:Info: $$LocaleString:"Address"
		Local		: Field: TSPL Customer Led States	: Add:Info: $$LocaleString:"State"
		Local		: Field: TSPL Customer Led Pin		: Add:Info: $$LocaleString:"Pincode"
		Local		: Field: TSPL Customer Led Cont		: Add:Info: $$LocaleString:"Contact"
		Local		: Field: TSPL Customer Led Tel		: Add:Info: $$LocaleString:"Tel. No."
		Local		: Field: TSPL Customer Led FaxNo	: Add:Info: $$LocaleString:"Fax No."
		Local		: Field: TSPL Customer Led EmailAdd	: Add:Info: $$LocaleString:"Email"
		Local		: Field: TSPL Customer Led CB		: Add:Info: $$LocaleString:"Closing Balance"
		
		Border		: Thin Bottom
		

    [Line: TSPL CustomerDetailsXMLJSON]

		Fields      : TSPL Customer Led No, TSPL Customer Led Name, TSPL Customer Led Address, TSPL Customer Led States, TSPL Customer Led Pin, TSPL Customer Led Cont, TSPL Customer Led Tel, TSPL Customer Led FaxNo, TSPL Customer Led EmailAdd, TSPL Customer Led CB
		JSONTag		: "Customer Details"
		Repeat		: TSPL Customer Led CB
		
		Local		: Field: Default: Pre Printed Border: Yes         ;; When printed on pre printed paper border corresponding to the fields will be ignored

        [Field: TSPL Customer Led No]

			Set as      : $$Line		
			Width       : 3
			Align       : Centre
			Border      : Thin Right
			Alter       : Ledger                                      ;; When user presses ctrl+enter on any line, corresponding ledger alteration screen is opened
			Skip Cell	: Yes                                         ;;This field value will not be printed in the excel export

			JSONTag		: "Customer No."
			Fixed		: Yes                                       ;;This field remains fixed and cursor doesnt scroll through it
			
        [Field: TSPL Customer Led Name]

			Use         : Name Field
			Set as      : $Name			
			Variable	: Ledger Name                                ;;Field value is held in this variable to be used in the ledger voucher drilldown report
			Display		: Ledger Vouchers                            ;;Report showing vouchers of the drilled down ledger is opened
			Border      : Thin Right
			Quick Search: Yes                                        ;;line cursor moves to the ledger name corresponding to the chracter typed 
			Cell		: 2                                          ;;Field value occupies 2 cells in excel export
			JSONTag		: "Customer Name"                            ;;This will be the tag corresponding to the field in JSON and XML export of the report
			XML Attr 	: "TYPE":"Name"                              ;;This will be exported as xml attribute along with the tag of the field
			
        [Field: TSPL Customer LedAddress]

			Set as      : $STPartyFullAdd
			Width       : 30
			Lines		: 0
			Border      : Thin Right
			JSONTag		: "Customer Address"
			Scroll		: Yes                                        ;;From this field onwards the fields scroll to the next page 

        [Field: TSPL Customer Led States]

			Set as      : $StateName
			Width       : 10
			Border      : Thin Right
			JSONTag		: "Customer State"

        [Field: TSPL Customer Led Pin]

			Set as      : $PinCode
			Width       : 10
			Border      : Thin Right
			JSONTag		: "Customer Pin"
			

        [Field: TSPL Customer Led Cont]

			Set as      : $LedgerContact
			Width       : 10
            Border      : Thin Right
			JSONTag		: "Customer Contact"
			

        [Field: TSPL Customer Led Tel]

			Set as      : $LedgerPhone
			Width 	    : 10
            Border      : Thin Right
			JSONTag		: "Customer Phone"
			

        [Field: TSPL Customer Led FaxNo]

			Set as      : $LedgerFax
			Width       : 10
			Border      : Thin Right
			JSONTag		: "Customer Fax"
			

        [Field: TSPL Customer Led EmailAdd]

			Set as      : $Email
			Width   	: 20
			Border      : Thin Right
			JSONTag		: "Customer Email"
			
        [Field: TSPL Customer Led CB]

            Use         : Amount Field
			Set as      : $ClosingBalance
			DMPMode 	: Bold                                           ;; Sets the printing style of the field to bold when its printing in dot matrix printer
			JSONTag		: "Customer Closing Balance"
			
						

[Collection: TSPL CustomerDetails]	

    Type	: Ledger

	Fetch	: Name, STPartyFullAdd, StateName, Pincode, LedgerContact, LedgerPhone, LedgerFax, Email, ClosingBalance
	Filter	: TSPLCustomerFilter
	
[System: Formula]
	
	TSPLCustomerFilter: $$IsLedOfGrp:$Name:$$GroupSundryCreditors OR $$IsLedOfGrp:$Name:$$GroupSundryDebtors 
	

	

;;EOF