;; Sri Ganeshji : Sri Balaji : Sri Pitreshwarji : Sri Durgaji : Sri Venkateshwara

/*
Objective(s) 
- 	This program illustrates the use of following attributes of Object 

Current Report
Current Collection
Use

About the Program
- This program illustrates adding reports to Goto and the browser list
- In Goto 2 items are added in the end of common reports section. One opens Party details report , other opens party ledger list and 
- with selection of ledger , ledger vouchers report is opened
- Connect your company, login to Tally website, login with your credentials to view the browser reports
- in the browser list 2 items are added in the end of the table. One opens Party details report , other opens party ledger list and 
- with selection of ledger , ledger vouchers report is opened


*/




;;Adding Objects in the default browser collection
[#Collection: List of Custom Browser Reports]

	Add : Object : TSPL Party Contact Details
	Add : Object : TSPL Party Ledger Display

[Object: TSPL Party Contact Details]

	Name              : "Party Contact Details"          ;Display Name in table
	CurrentReport     : TSPL Party Details               ;Report to be opened      
	DisplayReport     : "TSPL CustomerDetails"           ;Report to be opened
	IsAccessAvailable : $$Allow:Display:AccountsMasters  ;Condition for making this availble for logged in user based on permissions given in security of the company
	IsFeatureEnabled  : $$IsAccountingOn                 ;Condition to enable this based on company settings
	
[Object: TSPL Party Ledger Display]

	Name              : "Party Ledger Vouchers"
	Current Collection: TSPL Party Ledger                ;Collection to be displayed  
	DisplayCollection : "TSPL Party Ledger"              ;Collection to be displayed
	IsAccessAvailable : $$Allow:Display:AccountsMasters
	IsFeatureEnabled  : $$IsAccountingOn

;;Report showing party details	
[Report: TSPL Party Details]
	
	Use		: TSPL CustomerDetailsXMLJSON
	Local	: Field: Default : Delete: Border
	
;;Collection used in Current Collection
[Collection: TSPL Party Ledger]
	
	Use		: Ledger Vouchers
	Delete	: Trigger
	Add		: Trigger: TSPLTriggerReport
	
[Report: TSPLTriggerReport]
	
	Use		: Ledger Name
	Local	: Collection    : List of ExtractLedgers: Add: Filter: TSPLPartyFilter
	
[System: Formula]
	
	TSPLPartyFilter: $$IsLedOfGrp:$Name:$$GroupSundryCreditors OR $$IsLedOfGrp:$Name:$$GroupSundryDebtors


;;Adding items to the default Goto reports
[#Table: GT CommonReports]
	
	Add	: Object	: At End	: TSPL GT PartyContactDetails
	Add	: Object	: At End	: TSPL GT PartyLedgerColl

[Object	: TSPL GT PartyContactDetails]

	Use				: Go To Report Obj                                  ;;Uses default Object which has methods and actions related to goto items
	Action			: Goto Action		: Display Current Collection    ;;Displays the report mentions in currentreport attribute

	Name			: $$LocaleString:"Party Ledgers"                     ;;Display name in the Goto list
	Current Report	: TSPL CustomerDetailsXMLJSON                        ;;Report to be displayed

[Object: TSPL GT PartyLedgerColl]
	
	Use		: GT Collection Template Object                              ;;Uses default Object which has methods and actions related to goto items
	Name	: "Party Ledger Display"
	Action	: Goto Action		: Display Current Collection             ;;Displays the collection mentions in currentcollection attribute
	Action	: Display Action	: DisplayCurrentCollection
	Current Collection: TSPL Party Ledger                                ;;Collection to be displayed

	
[Include: tabulardisplay.tdl]


;EOF