;; Sri Ganeshji : Sri Balaji : Sri Pitreshwarji : Sri Durgaji : Sri Venkateshwara

/*

Objective

	- This code demonstrates the use of Watermark capability in Report Print. 
	- It allows you to place light text or images on the document to show branding, 
	  ownership, or status, without affecting the main content.

Last modification
		
		Created on 05/05/2026

*/

[Report: TSPL WatermarkCapabilities]
	
	Title			: $$LocaleString:"Watermark Capabilities"
	Form			: TSPL WatermarkCapabilities

[Form: TSPL WatermarkCapabilities]
	
	Use				: TSPL SMP Illustration
	Delete			: Option
	Add				: Button:  Blank Button 1,Blank Button 2,Blank Button 3,Blank Button 4,Blank Button 5,Blank Button 6,Blank Button 7, TSPL BalanceSheetBtn
		
	Height			: 100% Screen
	Width			: 100% Screen
	
	Local	: Part	: TSPL SMP Syntax		: Invisible	: Yes
	Local	: Field	: FormSubTitle			: Info		: $$LocaleString:"Illustration of Watermark Capabilities"
		
	Local	: Line	: TSPL SMP Example		: Delete	: Space Bottom
	Local	: Field	: TSPL Smp Purpose		: Indent	: 2
	Local	: Field	: TSPL Smp Purpose		: Info		: $$NewLine + $$LocaleString:"This code demonstrates the adding of Watermark in Balance Sheet Print using the Watermark capabilities."
	Local	: Field	: TSPL Smp Purpose		: Line		: 0
	Local	: Field	: TSPL Smp Purpose		: Style		: Normal

	
	Local	: Field	: TSPL SMP Example		: Indent	: 2
	Local	: Field	: TSPL SMP Example		: Info		: $$NewLine + +	"[Form:  TSPL BalanceSheet]" + $$NewLine + +
														  " Watermark	: BS Watermark"	+ $$NewLine + +
														  + $$NewLine + +														  
														  "[Watermark : BS Watermark]" + $$NewLine + +
														  " Type      	: Text " + $$NewLine + +
														  " Info       	 : BALANCE SHEET" + $$NewLine + +				
														  " Watermark Size: 20 " + $$NewLine ++				
														  " Opacity   	: 20%" + $$NewLine + $$NewLine 
													 																 
	Local	: Field	: TSPL SMP ExampleNote	: Style		: Normal Italic 
	Local	: Field	: TSPL SMP ExampleNote	: Key		: TSPLExampleCode
	Local	: Field	: TSPL SMP ExampleNote	: Info		: "For more details, refer to the help article from https://help.tallysolutions.com/developer-reference/" + $$NewLine + $$NewLine ++
														 "To experience this, please follow the steps provided below:" + $$NewLine + + $$NewLine + +
														  "	1. Click on the 'Balance Sheet' button on the right panel or press Ctrl + B to open it." + $$NewLine + +
														  " 2. The Balance Sheet print will show a watermark." 

;;=============== Button to Print Balance Sheet

[Button: TSPL BalanceSheetBtn]
	
	Title : "Balance Sheet" 
	Key	  : Ctrl + B
	Action: Print : TSPL BalanceSheet

;;=============== Report to Print Balance Sheet

[Report: TSPL BalanceSheet]
	
	Form	 :  TSPL BalanceSheet
	Set		 :  SVPreview	: Yes

[Form:  TSPL BalanceSheet]
	
	Use		 : Balance Sheet
	
	;;It allows users to overlay semi-transparent text or images onto documents. 
	Watermark	: TSPL BS Watermark	

;---------------- WATERMARK ----------------------------		
;It is used to create Watermark for the Print Template that can be used at Form Definition like [!Form : Tst New Template 1]
[Watermark : TSPL BS Watermark]
	
  Type      	 : Text
  Info      	 : "DRAFT"
  Watermark Size : 60
  Color     	 : 192, 192, 192
  Alignment 	 : $$SysName:Diagonal
  Opacity		 : 20

;;End of File